项目

常规

个人资料

操作
历史记录

指南 » 开发者指南 » REST API »

使用Perl的REST API

以下是一些Perl脚本，展示了如何使用Redmine REST API。它们从区域环境变量中猜测文件编码。有关详细信息，请参阅open。

GET

#!/usr/bin/perl
#    restget : GET a representation of a REST resource
use strict;
use warnings;
use Getopt::Std;
use LWP::UserAgent;
use JSON;
use open ':locale';    # probe the locale environment variables like LANG

sub HELP_MESSAGE {
    print STDERR <<"EOM";
usage : $0 [-p] [-k API_KEY] url
        -p: pretty print
        -k API_KEY: API Access Key
EOM
    exit 0;
}
our ($opt_p, $opt_k);
getopts('pk:') or HELP_MESSAGE();
my $url = shift;
HELP_MESSAGE() unless $url;
#################################################
my $ua = new LWP::UserAgent;
$ua->timeout(10);    # default: 180sec
$ua->ssl_opts( verify_hostname => 0 );    # skip hostname verification
$ua->default_header('X-Redmine-API-Key' => $opt_k) if $opt_k;

my $res = $ua->get($url);
die $res->message if $res->is_error;

my $content =  $res->content;
utf8::decode($content);    # convert UTF-8 binary to text
if ($opt_p) {        # pretty print
    my $perl_ref = from_json($content);
    print to_json($perl_ref, {pretty=>1});
} else {
    print $content, "\n";
}
exit 0;

注意


    my $perl_ref = from_json($content);

在这里，一个Perl引用" $perl_ref"是一个解析整个数据结构的引用。

使用示例


./restget https://redmine.ruby-lang.org.cn/issues/22097.json
./restget -k 57acc39afc967564aa79a6bd329897d7040a9bc8 http://demo.redmine.org/issues/117594.json

以下命令将一个文本表格放入剪贴板。


./restget https://redmine.ruby-lang.org.cn/projects/redmine/versions.json | perl -MJSON -nle 'for $v (sort{$a->{name} cmp $b->{name}}@{decode_json($_)->{versions}}){$d=$v->{description};print qq/|version:"$v->{name}"|$d|/ if $d}' > /dev/clipboard

您可以将它粘贴到Wiki页面上，如下所示。

0.7.1 错误修复版本
0.7.2 错误修复版本
0.7.3 安全+错误修复版本
0.9.0 0.9版本候选1
0.9.6 安全版本
1.0.1 1.0.0 RC的修复错误 - (预计发布日期)
1.2.3 1.2.x系列的错误修复版本
1.3.1 维护版本
1.4.3 维护版本
1.4.7 安全版本
2.0.2 维护版本
2.6.10 由于JRuby Nokogiri/Loofah不支持Rails 4.2，因此针对Rails 3.2
下一个主要版本的候选版本 贡献者希望在下一个主要版本中添加的功能
下一个次要版本的候选版本 贡献者希望在下一个次要版本中添加的修复
版本:"未计划" Redmine核心贡献者希望在将来的版本中添加的功能

PUT

#!/usr/bin/perl
#    restput : PUT a representation of a REST resource
use strict;
use warnings;
use Getopt::Std;
use LWP::UserAgent;
use open ':locale';    # probe the locale environment variables like LANG

sub HELP_MESSAGE {
    print STDERR <<"EOM";
usage : $0 [-p API_KEY] url [files...]
        -k API_KEY: API Access Key
EOM
    exit 0;
}
our ($opt_k);
getopts('k:') or HELP_MESSAGE();
my $url = shift;
HELP_MESSAGE() unless $url;
#################################################
my $ua = new LWP::UserAgent;
$ua->timeout(10);    # default: 180sec
$ua->ssl_opts( verify_hostname => 0 );    # skip hostname verification
$ua->default_header('X-Redmine-API-Key' => $opt_k) if $opt_k;

my $content;
{
    local $/;
    $content = <>;    # gets whole input
}
utf8::encode($content);    # convert UTF-8 binary to text
my $res = $ua->put($url,
                   'Content-Type' => 'application/json;charset=utf-8',
                   'Content' => $content);
die $res->message if $res->is_error;
print $res->content();
exit 0;

使用示例


# change my name
echo '{"user":{"firstname":"James","lastname":"Bond"}}' | ./restput -k 57acc39afc967564aa79a6bd329897d7040a9bc8 http://demo.redmine.org/users/current.json

以下脚本将Wiki内容转换为JSON格式。

#!/usr/bin/perl
#    restwiki : convert a Wiki content to JSON format
use strict;
use warnings;
use Getopt::Std;
use JSON;
use open ':locale';

sub HELP_MESSAGE {
    print STDERR <<"EOM";
usage :    $0 [-c comment] [files...]
    -c : comment
EOM
    exit 0;
}
our ($opt_c);
getopts('c:') or HELP_MESSAGE();
#################################################
my $ref;
{
    local $/;    # enable slurp mode
    $ref->{wiki_page}->{text} = <>;
}
$ref->{wiki_page}->{comments} = $opt_c if $opt_c;
print to_json($ref);
exit 0;

以下命令创建或更新一个Wiki页面"测试页面"。


./restwiki foo | ./restput -k 57acc39afc967564aa79a6bd329897d7040a9bc8 http://my.redmine.local/projects/test-project/wiki/Test_Page.json

您可能希望像这样进行一行操作；


perl -MJSON -e 'local $/;$ref->{wiki_page}->{text} = <>;print to_json($ref)' foo | ./restput -k 57acc39afc967564aa79a6bd329897d7040a9bc8 http://my.redmine.local/projects/test-project/wiki/Test_Page.json

资源

由Hiroo Hayashi更新 8年前 · 2次修订